Saturday, March 28, 2009

Feral Macros

UPDATE 4/20/09 - Mangle ability name changed.
UPDATE 6/11/09 - [spec] and [btn] modifiers, and reworked the keybind commentary.
UPDATE 3/17/10 - A few changes/updates.
UPDATE 10/26/10 - patch 4.0 updates


These macros are intended for Feral DPS and Tanking. They have been made specifically for keybinding purposes and to combine multiple abilities into one key. You can, of course, replace shift or alt with the ctrl key if you find it more comfortable. I included notes on my keybinds for each, as suggestions.

For more macros that are useful cross-class, see the Generic Macros post. An introduction to building macros is available here.


Table of Contents:




Catform / Prowl:

I bound this to my 3 key.

/stopcasting
/cancelform [flying]
/cast [noform:3] [combat] !Cat Form; Prowl

  • If not in cat form, will turn you to cat form.
  • Cat form: will use Prowl (or cancel Prowl if already prowling).
  • If in combat, it will recast Cat Form (useful for escaping snares).
  • If flying, it will cancel your form (such as flight form) to shift you into cat, so mind your height!


An alternative that does Dash in combat is below:
/stopcasting
/cancelform [flying]
/cast [noform:3] Cat Form; [nocombat] Prowl; Dash



Bearform / Feral Charge - Bear:
I bound this to my 1 key.

#showtooltip Feral Charge - Bear
/stopcasting
/cancelform [flying]
/cast [noform:1] Bear Form; Feral Charge(Bear Form)

  • If not in bearform, will turn you to bear form.
  • Bear form: will use Feral Charge.
  • If flying, it will cancel your form (such as flight form) to shift you into bear, so mind your height! This is useful for "bear bombing" from the air.


Feral Charge:
I bound this to my G12 key on my G15 keyboard.

#showtooltip
/cast [form:1] Feral Charge(Bear Form); [form:3] Feral Charge(Cat Form)
/stopmacro [form:1/3]
/cast [@mouseover,help] [help] [@player] Wild Growth

  • Bear form: it will cast Feral charge - Bear.
  • Cat form: it will cast Feral Charge - Cat.
  • If you are in neither form, it will cast Wild Growth. Replace this spell with another of your caster preference, if you desire; I keep it as wild growth so that I don't have to remap my keybinds when I respec.


Travel Forms:
I bound this to my 4 key.

/dismount
/castrandom [swimming] Aquatic Form; [flyable,nocombat] Swift Flight Form; [combat] [ ] !Travel Form

  • If you are swimming, it will cast Aquatic Form.
  • If the area allows flying and you are not in combat, it will cast Swift Flight Form.
  • If you are in combat or the area does not allow flying, it will cast Travel Form.
The cheetah portion is NOT sticky, so if you are in Travel Form already in a non-swimming, not-flyable area, it will recast travel form; this is useful for quickly escaping snares or roots in battlegrounds.


Cat FB, Rip, and Maim, and Bear Lacerate, Maul, and Mangle toggle:
I bound this to my "e" key in feral forms.

#showtooltip
/cast [form:3,mod:alt]Rip;[mod:shift,form:3] Ferocious Bite;[form:3] Maim
/stopmacro [form:3]
/cast [nomod:alt] !Maul
/cast [mod:shift] Pulverize; Lacerate

Cat form:
Bear form:
  • Standard click will queue up a Maul on your next attack, and cast Lacerate.
  • Shift-click for Pulverize.
  • Alt-click to use Lacerate only, such as if you need to avoid breaking CC with a two-target Maul or if your rage is low.


Swipes, Cat Rake, and Bear Bash toggle:
I bound this to my "q" key in feral forms.

#showtooltip
/cast [mod:shift,form:1] Thrash; [mod:alt,form:1] Mangle(Bear Form); [@mouseover,harm,nodead,form:1] [form:1] Swipe(Bear Form); [stealth] Pounce; [mod:shift] Rake; [@mouseover,harm,nodead] [] Swipe(Cat Form)
/startattack [nostealth]

Cat form:
  • If in stealth, it will cast Pounce.
  • Standard click for Swipe, with mouseover targeting.
  • Shift-click for Rake.
Bear form:
  • Standard click for Swipe, with mouseover targeting.
  • Shift-click for Thrash.
  • Alt-click for Mangle.

Bear Taunts/Roars toggle:
I bound this to my middle mouse button in bear form.

#show Growl
/stopcasting
/cast [mod:shift] Demoralizing Roar; [mod:alt] Challenging Roar; [harm] [@targettarget,harm] Growl
/startattack

  • Standard click will Growl either your current enemy target, or on your friendly target's own target, if that is an enemy.
  • If shift is held, it will cast Demoralizing Roar.
  • If alt is held, it will cast Challenging Roar.
  • In all cases, it will start up your auto-attack.


Cat Shred, Ravage, Mangle toggle with Tiger's Fury (plus Cyclone and Moonfire):
I bound this to my middle mouse button in all forms but bear.

#showtooltip
/cast [mod:alt] Tiger's Fury
/cast [mod:shift,form:3] [mod:alt]Shred; [stealth] Ravage;[form:3] Mangle(Cat Form);[mod:shift] Moonfire; [harm,nodead][@focus,harm,nodead] [] Cyclone
/startattack [nostealth,harm]

Cat form:
  • If in stealth, it will cast Ravage.
  • Otherwise, on a normal click, it will cast Mangle. If you do not know Mangle(Cat Form), replace it with Claw.
  • If shift-clicked, it will cast Shred.
  • If alt-clicked, it will cast Tiger's Fury in combination with any of the above (stealthed will be Tiger's Fury + Ravage, nostealth would be Tiger's Fury + Shred).
Caster form:
  • If shift-clicked, it will cast Moonfire: a great way to kill totems or other small things.
  • Normally clicked, it will cast Cyclone first on your enemy focus target, else on your target.


Faerie Fires, with Tiger's Fury toggle:
While technically keybound to "y" on both of my druids, I rarely stretch to press that key in combat, so I have it bound to an extra mouse button as well. It has a place on my screen because it contains so many useful cooldowns that I want to monitor.

Pure Feral:
#showtooltip
/cast [mod:shift,form:3] Tiger's Fury; [mod,form:1] Skull Bash(Bear Form); [mod:alt,form:3] Skull Bash(Cat Form); [form:1/3] Faerie Fire (Feral)(); Faerie Fire


Resto primary/Feral secondary Spec Variant for cooldown monitoring:

#showtooltip
/cast [mod:shift,form:3] Dash; [form:1/3,mod:alt] Skull Bash;[@mouseover,harm,nodead,form:1/3][form:1/3]Faerie Fire (Feral)(); [mod:shift,spec:1] Swiftmend; [mod:alt,spec:1] Nature's Swiftness;[@mouseover,harm][] Faerie Fire


Kitty Charge + Ravage:
I bound this to my "t" key in cat form.

#showtooltip
/cast [mod] Savage Roar
/stopmacro [spec:1]
/castsequence reset=8 Feral Charge(Cat Form), Ravage, Mangle(Cat Form)

Cat Form:



Bear Enrage/Frenzied Regeneration/Challenging Roar and Cat Dash/Savage Roar:
I bound this to my "t" key in feral forms, and use it as a cooldown monitor visible on my screen.

#showtooltip
/cast [mod:shift,form:3] Savage Roar; [form:3] Dash; [btn:2][mod:shift] Enrage; [mod:alt] Challenging Roar
/stopmacro [noform:1]
/cast [btn:1] [mod:shift] Frenzied Regeneration
/stopmacro [btn:2]
/s You no take cookie!

Announces in /say if you have cast Frenzied Regen. Replace the red text with your own Frenzied Regen announcement, or remove it if you prefer.

Bear form:
Cat Form:


Trinket + Mangles:
I bound this to my "g" key in feral forms, and keep it visible on my screen to watch the cooldowns.

#showtooltip [mod:shift] 13; 14
/use 13
/use 14
/cast [form:1] Mangle(Bear Form); [form:3] Mangle(Cat Form); [@mouseover,help] [help] [@player] Rejuvenation

  • Standard click to use both of your trinkets and cast a form-appropriate Mangle.
  • If you are in any other form, it will cast rejuvenation via mouseover with your trinket instead of mangle. This is useful when using healing trinkets.
  • If necessary, replace Mangle(Bear Form) with Maul, and Mangle(Cat Form) with Claw.


Defensive Abilities + Tranquility:
Keybound to H as well as a mouse button, and I also keep the macro visible prominently on my screen to watch the cooldowns and click things as needed.

#showtooltip
/cast [form:1/3,mod:shift] Survival Instincts; [mod:alt] Nature's Grasp; [btn:2] Hurricane; [mod:shift] Tranquility
/cast Barkskin
/stopmacro [nomod:shift] [form:1/3]
/s Pretty lights! Gather close for healing!

  • In all cases (including a normal click), it casts Barkskin.
  • If Shift-clicked while in cat or bear form, it casts Survival Instincts.
  • If Shift-clicked and you are not in cat or bear form, it casts Tranquility and announces to everyone that they need to be near you to get the heals. Replace the red text for your on Tranquility announcement, or remove it as desired.
  • If Alt-clicked in any form, it casts Nature's Grasp.
  • If the macro is right-clicked, it will cast Hurricane.


~~If you need help or would like to see one of these macros more customized for your spec, feel free to ask in the comments! ~~

5 comments:

z32o said...

Thank you for this, it's great utility :)

Amezor said...

Hey Kae,

Fist off: Great site! These macros really make my life alot easyer :D.

Im having trouble linking my healing spells in the same macro as my feral abilities.

* Cat FB macro: I'd like to add Nourish and Healing Touch when in caster form (the latter with shift as a modifier)

* Cat shred macro: In caster form i'd like it to be Rejuv. and Lifebloom. I managed to to this with just adding /cast at the end, hence my confused state about the cat FB macro :P. Can't seem to link it anywhere.

Much thanks in advance,

Amezor

Kae said...

The FB macro I posted is too long to add much more to it, much less two abilities. I think your problem with the FB macro was that I don't have form modifiers in for the bear attacks: it assumes that if you aren't in cat, then you're in bear. If you strip out the bear stuff, though, you'd end up with:

#showtooltip
/cast [mod:shift,form:3] Ferocious Bite; [form:3,mod:alt] Rip; [form:3] Maim; [mod:shift] Healing Touch; Nourish

...then, for the shred, you can try this, which has stripped out the cyclone and replaced it with heals:

#showtooltip
/cast [mod:alt,form:3] Tiger's Fury
/cast [mod:shift,form:3] Shred; [nostealth,form:3] Mangle (Cat)(); [stealth] Ravage; [mod:shift] Lifebloom; [harm,nodead] Moonfire; Rejuvenation
/startattack [nostealth,harm]

Hope these work for you :)

Amezor said...

Thank you so much! And also for the fast response!

/hug!

Amezor

Matt Coles said...

Hey Mate,

Thanks for these macros theyre great and will help me alot.

Ive been trying to fiddle around and make my own macros and im having mixed results.

Idealy what i would like is a macro for cat form (whilst in stealth) that will feral charge, ff, pounce than ravage all in one. ive been having trouble gettin the ff to work.

Also one for my bleeds. so one that will Tigers fury, mangle, rake than rip.

I was also thinking of one that will help with healing in arena.. so maybe a one that will work on a team mate if ur mouse is over him n if its not it casts on you.. so one that u can use in any form cat bear which will switch you to caster form. than cast rejuv and regrowth than switch you back to what form you were in..

I would really really appreciate it if you could give me a hand on gettin these macros up and going..

You can email me a freaky_matt_@hotmail.com

Thanks heaps,

Matt